Extract bos-settings to its own repo; add breadhelp; JSON-driven Hyprland config

bos-settings moves to git.breadway.dev/Breadway/bos-settings (full history
preserved via git-filter-repo) so its release cadence is decoupled from
BOS's own. breadhelp takes its place as this repo's workspace member: a
GTK4 onboarding/help center replacing the old bos-welcome/bos-keybinds
bash scripts with searchable guides, an interactive keybind viewer
(sourced from the new keybinds.toml, not parsed out of hyprland.lua or
hardcoded), a troubleshooting wizard with one-click fixes, and a proper
first-run tour. bos-netcheck extracts bos-welcome's network-check half,
which still needs to run every login independent of breadhelp's own
first-run gating.

hyprland.lua's keybinds/settings/monitors/autostart are now JSON-driven
(binds.json/settings.json/monitors.json/autostart.json) with every
loader pcall-wrapped and falling back to hardcoded defaults per field on
bad or missing config, so bread* apps (bos-settings' new editors, and
breadhelp's keybind viewer) can read/write this config without ever
being able to leave the compositor unable to start.

CI's package.yml now builds breadhelp instead of bos-settings on tag
push; bos-settings needs its own equivalent workflow in its new repo
(not yet set up).

packaging/arch/breadhelp/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Breadway <rileyhorsham@gmail.com>
+
+pkgname=breadhelp
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="Onboarding and help center for Bread OS"
+arch=('x86_64')
+url="https://github.com/Breadway/bos"
+license=('MIT')
+# Some Rust deps (ring/mlua) build vendored C/asm into static archives; makepkg's
+# default -flto=auto emits GCC LTO bitcode the Rust (lld) link cannot read,
+# causing undefined-symbol errors. Disable LTO.
+options=(!lto !debug)
+depends=('gtk4' 'glib2' 'hicolor-icon-theme')
+optdepends=(
+  'snapper: create-backup one-click fix'
+)
+makedepends=('rust' 'cargo')
+source=("${pkgname}-${pkgver}.tar.gz")
+sha256sums=('SKIP')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  cargo build --release --locked -p breadhelp
+}
+
+check() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  cargo test --release --locked -p breadhelp
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  install -Dm755 target/release/breadhelp "${pkgdir}/usr/bin/breadhelp"
+  install -Dm644 packaging/arch/breadhelp/breadhelp.desktop \
+    "${pkgdir}/usr/share/applications/breadhelp.desktop"
+  install -d "${pkgdir}/usr/share/breadhelp"
+  cp -r breadhelp/content "${pkgdir}/usr/share/breadhelp/content"
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}