# Maintainer: Breadway <rileyhorsham@gmail.com>

pkgname=breadhelp
pkgver=0.1.0
pkgrel=1
pkgdesc="Onboarding and help center for Bread OS"
arch=('x86_64')
url="https://github.com/Breadway/bos"
license=('MIT')
# Some Rust deps (ring/mlua) build vendored C/asm into static archives; makepkg's
# default -flto=auto emits GCC LTO bitcode the Rust (lld) link cannot read,
# causing undefined-symbol errors. Disable LTO.
options=(!lto !debug)
depends=('gtk4' 'glib2' 'hicolor-icon-theme')
optdepends=(
  'snapper: create-backup one-click fix'
)
makedepends=('rust' 'cargo')
source=("${pkgname}-${pkgver}.tar.gz")
sha256sums=('SKIP')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo build --release --locked -p breadhelp
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo test --release --locked -p breadhelp
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  install -Dm755 target/release/breadhelp "${pkgdir}/usr/bin/breadhelp"
  install -Dm644 packaging/arch/breadhelp/breadhelp.desktop \
    "${pkgdir}/usr/share/applications/breadhelp.desktop"
  install -d "${pkgdir}/usr/share/breadhelp"
  cp -r breadhelp/content "${pkgdir}/usr/share/breadhelp/content"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}