# Maintainer: Breadway <rileyhorsham@gmail.com>

pkgname=bread
pkgver=0.6.0
pkgrel=1
pkgdesc="A reactive automation fabric for Linux desktops"
arch=('x86_64')
url="https://github.com/Breadway/bread"
license=('MIT')
# mlua builds Lua from vendored C source. makepkg's default -flto=auto would
# emit GCC LTO bitcode into liblua5.4.a, which the Rust (lld) link can't read,
# leaving all lua_* symbols undefined. Disable LTO for a clean static link.
options=(!lto)
depends=('glibc' 'libgit2')
optdepends=(
  'libnotify: desktop notifications via bread.notify()'
  'upower: D-Bus battery events (sysfs polling used otherwise)'
  'git: bread sync push/pull operations'
)
makedepends=('rust' 'cargo')
source=("${pkgname}-${pkgver}.tar.gz")
sha256sums=('SKIP')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo build --release --locked
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo test --release --locked --workspace
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  install -Dm755 target/release/breadd "${pkgdir}/usr/bin/breadd"
  install -Dm755 target/release/bread  "${pkgdir}/usr/bin/bread"
  install -Dm644 packaging/systemd/breadd.service "${pkgdir}/usr/lib/systemd/user/breadd.service"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}