# Maintainer: Breadway <rileyhorsham@gmail.com>

pkgname=breadbox
pkgver=0.1.0
pkgrel=1
pkgdesc="App launcher for Hyprland / Wayland"
arch=('x86_64')
url="https://github.com/Breadway/breadbox"
license=('MIT')
# Some Rust deps (ring/mlua) build vendored C/asm into static archives; makepkg's
# default -flto=auto emits GCC LTO bitcode the Rust (lld) link cannot read,
# causing undefined-symbol errors. Disable LTO.
options=(!lto !debug)
depends=('gtk4' 'gtk4-layer-shell' 'librsvg')
optdepends=(
  'hyprland: window and workspace integration'
)
makedepends=('rust' 'cargo')
source=("${pkgname}-${pkgver}.tar.gz")
sha256sums=('SKIP')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo build --release --locked
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cargo test --release --locked --workspace
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  install -Dm755 target/release/breadbox      "${pkgdir}/usr/bin/breadbox"
  install -Dm755 target/release/breadbox-sync "${pkgdir}/usr/bin/breadbox-sync"
  install -Dm644 packaging/breadbox-sync.service \
    "${pkgdir}/usr/lib/systemd/user/breadbox-sync.service"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
