38 lines
1.1 KiB
Bash
38 lines
1.1 KiB
Bash
# Maintainer: Breadway <plasticbread849@gmail.com>
|
|
|
|
pkgname=breadpad
|
|
pkgver=0.3.1
|
|
pkgrel=1
|
|
pkgdesc="Quick-capture scratchpad and note viewer with AI classification"
|
|
arch=('x86_64')
|
|
url="https://git.breadway.dev/Breadway/breadpad"
|
|
license=('MIT')
|
|
# Some Rust deps (ring/mlua) build vendored C/asm into static archives; makepkg's
|
|
# default -flto=auto emits GCC LTO bitcode the Rust (lld) link cannot read,
|
|
# causing undefined-symbol errors. Disable LTO.
|
|
options=(!lto !debug)
|
|
depends=('gtk4' 'gtk4-layer-shell')
|
|
optdepends=(
|
|
'ollama: local AI note classification'
|
|
'hyprland: scratchpad window integration'
|
|
)
|
|
makedepends=('rust' 'cargo')
|
|
source=("${pkgname}-${pkgver}.tar.gz")
|
|
sha256sums=('SKIP')
|
|
|
|
build() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
cargo build --release --locked
|
|
}
|
|
|
|
check() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
cargo test --release --locked --workspace
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
install -Dm755 target/release/breadpad "${pkgdir}/usr/bin/breadpad"
|
|
install -Dm755 target/release/breadman "${pkgdir}/usr/bin/breadman"
|
|
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|